varnishtest "client abandoning hit-for-miss"

barrier b1 cond 2

server s1 {
	non_fatal
	rxreq
	txresp -nolen -hdr "Transfer-Encoding: chunked" -hdr "Set-Cookie: foo=bar"
	chunked "foo"
	barrier b1 sync
	chunked "bar"
	delay .1
	chunkedlen 64
	delay .1
	chunkedlen 64
	chunkedlen 0
} -start

varnish v1 -vcl+backend { } -start

client c1 {
	txreq
	rxresphdrs
	rxchunk
	barrier b1 sync
} -run

delay 2

server s1 {
	rxreq
	txresp
} -start

client c1 {
	txreq
	rxresp
	expect resp.status == 200
} -run
